CA1 network model for place cell dynamics (Turi et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:246546
Biophysical model of CA1 hippocampal region. The model simulates place cells/fields and explores the place cell dynamics as function of VIP+ interneurons.
Reference:
1 . Turi GF, Li W, Chavlis S, Pandi I, O’Hare J, Priestley JB, Grosmark AD, Liao Z, Ladow M, Zhang JF, Zemelman BV, Poirazi P, Losonczy A (2019) Vasoactive Intestinal Polypeptide-Expressing Interneurons in the Hippocampus Support Goal-Oriented Spatial Learning Neuron
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism: Hippocampus; Mouse;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell; Hippocampus CA1 basket cell; Hippocampus CA1 basket cell - CCK/VIP; Hippocampus CA1 bistratified cell; Hippocampus CA1 axo-axonic cell; Hippocampus CA1 stratum oriens lacunosum-moleculare interneuron ; Hippocampal CA1 CR/VIP cell;
Channel(s): I A; I h; I K,Ca; I Calcium; I Na, leak; I K,leak; I M;
Gap Junctions:
Receptor(s): GabaA; GabaB; NMDA; AMPA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; Brian;
Model Concept(s): Place cell/field;
Implementer(s): Chavlis, Spyridon [schavlis at imbb.forth.gr]; Pandi, Ioanna ;
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; GabaA; GabaB; AMPA; NMDA; I A; I K,leak; I M; I h; I K,Ca; I Calcium; I Na, leak;
/
Turi_et_al_2018
mechanisms
ANsyn.mod
bgka.mod
burststim2.mod *
cad.mod
cadyn.mod
cadyn_new.mod
cagk.mod *
cal.mod
calH.mod *
cancr.mod
car.mod *
cat.mod
ccanl.mod *
gskch.mod
h.mod
hha_old.mod *
hha2.mod
hNa.mod *
IA.mod
iccr.mod
ichan2.mod
ichan2aa.mod
ichan2bc.mod
ichan2bs.mod
ichan2vip.mod
Ih.mod *
Ihvip.mod
ikscr.mod *
kad.mod *
kadistcr.mod
kap.mod
Kaxon.mod
kca.mod
Kdend.mod
kdrcr.mod *
km.mod
Ksoma.mod
LcaMig.mod *
my_exp2syn.mod
Naaxon.mod
Nadend.mod
nafcr.mod *
nap.mod
Nasoma.mod
nca.mod *
nmda.mod
regn_stim.mod
somacar.mod
STDPE2Syn.mod *
vecstim.mod *
                            
TITLE ichan2vip.mod  
 
COMMENT
konduktivitas valtozas hatasa- somaban 
ENDCOMMENT
 
UNITS {
    (mA) =(milliamp)
    (mV) =(millivolt)
    (uF) = (microfarad)
    (molar) = (1/liter)
    (nA) = (nanoamp)
    (mM) = (millimolar)
    (um) = (micron)
    FARADAY = 96520 (coul)
    R = 8.3134  (joule/degC)
}
 
? interface 
NEURON { 
SUFFIX ichan2vip
USEION nat READ enat WRITE inat VALENCE 1
USEION kf READ ekf WRITE ikf  VALENCE 1
USEION ks READ eks WRITE iks  VALENCE 1
NONSPECIFIC_CURRENT il 
RANGE gnat, gkf, gks
RANGE gnatbar, gkfbar, gksbar
RANGE gl, el
RANGE minf, mtau, hinf, htau, nfinf, nftau, inat, ikf, nsinf, nstau, iks
}
 
INDEPENDENT {t FROM 0 TO 100 WITH 100 (ms)}
 
PARAMETER {
    v (mV) 
    celsius = 6.3 (degC)
    dt (ms) 
    enat  (mV)
    gnatbar (mho/cm2)   
    ekf  (mV)
    gkfbar (mho/cm2)
    eks  (mV)
    gksbar (mho/cm2)
    gl (mho/cm2)    
    el (mV)
}
 
STATE {
    m h nf ns
}
 
ASSIGNED {
         
    gnat (mho/cm2) 
    gkf (mho/cm2)
    gks (mho/cm2)

    inat (mA/cm2)
    ikf (mA/cm2)
    iks (mA/cm2)


    il (mA/cm2)

    minf hinf nfinf nsinf
    mtau (ms) htau (ms) nftau (ms) nstau (ms)
    mexp hexp nfexp nsexp
} 

? currents
BREAKPOINT {
    SOLVE states
    gnat = gnatbar*m*m*m*h  
    inat = gnat*(v - enat)
    gkf = gkfbar*nf*nf*nf*nf
    ikf = gkf*(v-ekf)
    gks = gksbar*ns*ns*ns*ns
    iks = gks*(v-eks)

    il = gl*(v-el)
}
 
UNITSOFF
 
INITIAL {
    trates(v)

    m = minf
    h = hinf
    nf = nfinf
    ns = nsinf

    VERBATIM
    return 0;
    ENDVERBATIM
}

? states
PROCEDURE states() {    :Computes state variables m, h, and n 
    trates(v)   :      at the current v and dt.
    m = m + mexp*(minf-m)
    h = h + hexp*(hinf-h)
    nf = nf + nfexp*(nfinf-nf)
    ns = ns + nsexp*(nsinf-ns)
    VERBATIM
    return 0;
    ENDVERBATIM
}
 
LOCAL q10

? rates
PROCEDURE rates(v) {  :Computes rate and other constants at current v.
                      :Call once from HOC to initialize inf at resting v.
    LOCAL  alpha, beta, sum
    
    :q10 = 3^((celsius - 6.3)/10)
    q10 = 1     : make temperature independent (BPG)
    
    :"m" sodium activation system - act and inact cross at -40
    alpha = -0.3*vtrap((v+41.5),-5)
    beta  = 0.3*vtrap((v+25),5)
    sum   = alpha+beta        
    mtau  = 1/sum      
    minf  = alpha/sum
    
    :"h" sodium inactivation system
    alpha = 0.23/exp((v+65)/20)
    beta  = 3.33/(1+exp((v+37.5)/-10))
    sum   = alpha+beta
    htau  = 1/sum 
    hinf  = alpha/sum 
    
    :"ns" sKDR activation system
    alpha = -0.88*vtrap((v+30),-6)
    beta  = 0.1056/exp((v+55)/40)
    sum   = alpha+beta        
    nstau = 1/sum      
    nsinf = alpha/sum
    
    :"nf" fKDR activation system
    alpha = -0.065*vtrap((v+18),-6)
    beta  = 0.264/exp((v+28)/40)
    sum   = alpha+beta        
    nftau = 1/sum      
    nfinf = alpha/sum
}
 
PROCEDURE trates(v) {  :Computes rate and other constants at current v.
                       :Call once from HOC to initialize inf at resting v.
    LOCAL tinc
    TABLE minf, mexp, hinf, hexp, nfinf, nfexp, nsinf, nsexp, mtau, htau, nftau, nstau
    DEPEND dt, celsius FROM -100 TO 100 WITH 200
                           
    rates(v)  : not consistently executed from here if usetable_hh == 1
              : so don't expect the tau values to be tracking along with
              : the inf values in hoc

    tinc  = -dt * q10
    mexp  = 1 - exp(tinc/mtau)
    hexp  = 1 - exp(tinc/htau)
    nfexp = 1 - exp(tinc/nftau)
    nsexp = 1 - exp(tinc/nstau)
}
 
FUNCTION vtrap(x,y) {  :Traps for 0 in denominator of rate eqns.
        if (fabs(x/y) < 1e-6) {
                vtrap = y*(1 - x/y/2)
        }else{  
                vtrap = x/(exp(x/y) - 1)
        }
}
 
UNITSON


Loading data, please wait...