DRG neuron models investigate how ion channel levels regulate firing properties (Zheng et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:256632
We present computational models for an Abeta-LTMR (low-threshold mechanoreceptor) and a C-LTMR expressing four Na channels and four K channels to investigate how the expression level of Kv1 and Kv4 regulate number of spikes (repetitive firing) and onset latency to action potentials in Abeta-LTMRs and C-LTMRs, respectively.
Reference:
1 . Zheng Y, Liu P, Bai L, Trimmer JS, Bean BP, Ginty DD (2019) Deep Sequencing of Somatosensory Neurons Reveals Molecular Determinants of Intrinsic Physiological Properties Neuron
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Mouse;
Cell Type(s): Dorsal Root Ganglion (DRG) cell;
Channel(s): I Sodium; I Potassium; I K; I A;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.6 SCN8A; Nav1.7 SCN9A; Nav1.8 SCN10A; Kv1.1 KCNA1; Kv1.2 KCNA2; Kv2.1 KCNB1; Kv3.1 KCNC1; Kv3.3 KCNC3; Kv3.4 KCNC4; Kv4.3 KCND3;
Transmitter(s):
Simulation Environment: NEURON; R;
Model Concept(s): Action Potential Initiation; Action Potentials; Activity Patterns; Delay; Ion Channel Kinetics; Membrane Properties;
Implementer(s): Zheng, Yang [zylittlep at gmail.com]; Bean, Bruce [bruce_bean at hms.harvard.edu];
Search NeuronDB for information about:  I A; I K; I Sodium; I Potassium;
: Kv2 channel 

UNITS {
    (mV) = (millivolt)
    (mA) = (milliamp)
    (S) = (siemens)
}

NEURON {
    SUFFIX kv2
    USEION k READ ek WRITE ik
    RANGE gkbar, gk, ik
    GLOBAL vhninf, kninf, antaul, bntaul, cntaul, dntaul, antaur, bntaur, cntaur,dntaur,brkvntau
}

PARAMETER{ 
    gkbar = 0.012 (S/cm2)
    ek = -88 (mV)
    vhninf = -32
    kninf = 8.6
    antaul = 15
    bntaul = 53.1
    cntaul = -46.3
    dntaul = 14
    brkvntau = -30
    antaur = 0.75
    bntaur = 23
    cntaur = -25.6
    dntaur = 4.6
}

ASSIGNED{
    v (mV)
    ik (mA/cm2)
    gk (S/cm2)
    ninf
    ntau (ms) 
}

STATE{
    n
}

BREAKPOINT{
    SOLVE states METHOD cnexp 
    gk = gkbar * n^4
    ik = gk * (v - ek)
}

UNITSOFF

INITIAL{
    settables(v)
    n = ninf
}

DERIVATIVE states{
    settables(v)
    n' = (ninf-n)/ntau
}

PROCEDURE settables(v (mV)){
    TABLE ninf, ntau
    FROM -100 TO 100 WITH 200  
    
    ninf = 1/(1+exp(-((v-vhninf)/kninf)))
    
    if (v < brkvntau){
         ntau = antaul+bntaul*(1/(1+exp(-(v-cntaul)/dntaul)))
    }else{
         ntau = antaur+bntaur*(1/(1+exp((v-cntaur)/dntaur)))
    }
}

UNITSON


Loading data, please wait...