DRG neuron models investigate how ion channel levels regulate firing properties (Zheng et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:256632
We present computational models for an Abeta-LTMR (low-threshold mechanoreceptor) and a C-LTMR expressing four Na channels and four K channels to investigate how the expression level of Kv1 and Kv4 regulate number of spikes (repetitive firing) and onset latency to action potentials in Abeta-LTMRs and C-LTMRs, respectively.
Reference:
1 . Zheng Y, Liu P, Bai L, Trimmer JS, Bean BP, Ginty DD (2019) Deep Sequencing of Somatosensory Neurons Reveals Molecular Determinants of Intrinsic Physiological Properties Neuron
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Mouse;
Cell Type(s): Dorsal Root Ganglion (DRG) cell;
Channel(s): I Sodium; I Potassium; I K; I A;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.6 SCN8A; Nav1.7 SCN9A; Nav1.8 SCN10A; Kv1.1 KCNA1; Kv1.2 KCNA2; Kv2.1 KCNB1; Kv3.1 KCNC1; Kv3.3 KCNC3; Kv3.4 KCNC4; Kv4.3 KCND3;
Transmitter(s):
Simulation Environment: NEURON; R;
Model Concept(s): Action Potential Initiation; Action Potentials; Activity Patterns; Delay; Ion Channel Kinetics; Membrane Properties;
Implementer(s): Zheng, Yang [zylittlep at gmail.com]; Bean, Bruce [bruce_bean at hms.harvard.edu];
Search NeuronDB for information about:  I A; I K; I Sodium; I Potassium;
: Nav1.1 

UNITS {
    (mV) = (millivolt)
    (mA) = (milliamp)
    (S) = (siemens)
}

NEURON {
    SUFFIX nav1p1
    USEION na READ ena WRITE ina
    RANGE gnabar, gna, ina
    GLOBAL vhminf, kminf, amtaul, bmtaul, cmtaul, dmtaul, amtaur, bmtaur, cmtaur, dmtaur,brkvmtau
    GLOBAL vhhinf, khinf, ahtaul, bhtaul, chtaul, dhtaul, ahtaur, bhtaur, chtaur, dhtaur, brkvhtau
}

PARAMETER{ 
    gnabar = 0.008 (S/cm2)
    ena = 55 (mV)
    vhminf = -35
    kminf = 5.5
    amtaul = 0.006
    bmtaul = 0.08
    cmtaul = -55
    dmtaul = 12
    brkvmtau = -50
    amtaur = 0.015
    bmtaur = 0.065
    cmtaur = -10.8
    dmtaur = 10
    vhhinf = -40
    khinf = 12
    ahtaul = 1.98
    bhtaul = 8.54
    chtaul = -73.3
    dhtaul = 4.7
    brkvhtau = -55
    ahtaur = 0.17
    bhtaur = 10.82
    chtaur = -39.1
    dhtaur = 4.59
}

ASSIGNED{
    v (mV)
    ina (mA/cm2)
    gna (S/cm2)
    minf
    hinf
    mtau (ms) 
    htau (ms)    
}

STATE{
    m h
}

BREAKPOINT{
    SOLVE states METHOD cnexp
    
    gna = gnabar * m^3 * h
    ina = gna * (v - ena)
}

UNITSOFF

INITIAL{
    settables(v)
    m = minf
    h = hinf
}

DERIVATIVE states{
    settables(v)
    m' = (minf-m)/mtau
    h' = (hinf-h)/htau
}

UNITSOFF

PROCEDURE settables(v (mV)){
    TABLE minf, mtau, hinf, htau
    FROM -100 TO 100 WITH 200

    minf = 1/(1+exp(-(v-vhminf)/kminf))

if (v < brkvmtau){
         mtau = amtaul+bmtaul*(1/(1+exp(-(v-cmtaul)/dmtaul)))
    }else{
         mtau = amtaur+bmtaur*(1/(1+exp((v-cmtaur)/dmtaur)))
    }

    hinf = 1/(1+exp((v-vhhinf)/khinf))

if (v < brkvhtau){
         htau = ahtaul+bhtaul*(1/(1+exp(-(v-chtaul)/dhtaul)))
    }else{
         htau = ahtaur+bhtaur*(1/(1+exp((v-chtaur)/dhtaur)))
    }

}

UNITSON


Loading data, please wait...