Retinal Ganglion Cell: I-CaN and I-CaL (Benison et al. 2001)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:3457
NEURON mod files for the CaN and CaL currents from the papers: Huang, S.-J. & Robinson, D.W. (1998). Activation and Inactivation properties of voltage-gated calcium currents in developing cat retinal ganglion cells. Neuroscience 85:239-247 (experimental) and Benison G. Keizer J., Chalupa L.M., Robinson D.W., (2001) J. theor. Biol. 210:187-199 (theoretical).
References:
1 . Benison G, Keizer J, Chalupa LM, Robinson DW (2001) Modeling temporal behavior of postnatal cat retinal ganglion cells. J Theor Biol 210:187-99 [PubMed]
2 . Huang SJ, Robinson DW (1998) Activation and inactivation properties of voltage-gated calcium currents in developing cat retinal ganglion cells. Neuroscience 85:239-47 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Channel/Receptor;
Brain Region(s)/Organism:
Cell Type(s): Retina ganglion GLU cell;
Channel(s): I L high threshold; I N;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics;
Implementer(s): Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Retina ganglion GLU cell; I L high threshold; I N;
TITLE CaN
: N-type Ca current for Retinal Ganglion Cell from Benison et al (2001)
: M.Migliore Nov. 2001

NEURON {
	SUFFIX canrgc
	USEION ca READ eca WRITE ica
	RANGE  gbar
	GLOBAL minf, hinf, mtau, htau
}

PARAMETER {
	gbar = 0.010   	(mho/cm2)	
								
	eca		(mV)            : must be explicitly def. in hoc
	v 		(mV)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	ica 		(mA/cm2)
	minf 		hinf 		
	mtau (ms)	htau (ms) 	
}
 

STATE { m h}

BREAKPOINT {
        SOLVE states METHOD cnexp
	ica = gbar*m*m*h * (v - eca)
} 

INITIAL {
	trates(v)
	m=minf  
	h=hinf
}

DERIVATIVE states {   
        trates(v)      
        m' = (minf-m)/mtau
        h' = (hinf-h)/htau
}

PROCEDURE trates(vm) {  
        LOCAL  a, b

	a = trap0(vm,20,0.1,10)
	b = 0.4*exp(-(vm+25)/18)
	minf = a/(a+b)
	mtau = 1/(a+b)

	a = 0.01*exp(-(vm+50)/10)
	b = 0.1/(1+exp(-(vm+17)/17))
	hinf = a/(a+b)
	htau = 1/(a+b)
}

FUNCTION trap0(v,th,a,q) {
	if (fabs(v-th) > 1e-6) {
	        trap0 = a * (v - th) / (1 - exp(-(v - th)/q))
	} else {
	        trap0 = a * q
 	}
}	

Loading data, please wait...