Spinal Motor Neuron (Dodge, Cooley 1973)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:3805
"The excitability of various regions of the spinal motorneuron can be specified by solving the partial differential equation of a nerve fiber whose diameter and membrane properties vary with distance. For our model geometrical factors for the myelinated axon, initial segment and cell body were derived from anatomical measurements, the dendritic tree was represented by its equivalent cylinder, and the current-voltage relations of the membrane were described by a modification of the Hodgkin-Huxley model that fits voltage-clamp data from the motorneuron. ..."
Reference:
1 . Dodge FA, Cooley JW (1973) Action Potential of the Motorneuron. IBM J Res Dev 17:219-29
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Spinal cord lumbar motor neuron alpha ACh cell; Myelinated neuron;
Channel(s): I Na,t; I K;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Simplified Models; Active Dendrites; Tutorial/Teaching; Axonal Action Potentials; Action Potentials;
Implementer(s): Hines, Michael [Michael.Hines at Yale.edu];
Search NeuronDB for information about:  Spinal cord lumbar motor neuron alpha ACh cell; I Na,t; I K;
load_file("nrngui.hoc")


nmyl = 1

create soma, dend, is, myelin[nmyl], node[nmyl], extra
access soma

objref ax, somden
ax = new SectionList()
forsec "node" ax.append()
is ax.append()
extra ax.append()

somden = new SectionList()
soma somden.append
dend somden.append

connect dend(0), soma(1)
connect is(0), soma(0)
connect myelin[0](0), is(1)
for i=0, nmyl-2 {
	connect node[i](0), myelin[i](1)
	connect myelin[i+1](0), node[i](1)
}
connect node[nmyl-1](0), myelin[nmyl-1](1)
connect extra(0) , node[nmyl-1](1)
// "extra" is a bit of unmyelinated axon for stimulating purposes

forall { Ra = 100  insert dc }
forsec ax shift_dc = -10

dend   		{ nseg = 30  cm = 1   }
soma		{ nseg = 6   cm = 1   }
is		{ nseg = 5   cm = 1   }
forsec "myelin" { nseg = 5   cm = .05 }
forsec "node"	{ nseg = 1   cm = 1   }
extra		{ nseg = 10   cm = 1   }

// relative to rest of 0 mV
vrest_dc = 0
forall {ena = 115  ek = -5  el_dc = 0 }

dend		{ diam=2*30  L=4500  gnabar_dc=0   gkbar_dc=0     gl_dc=.167e-3 }
soma		{ diam=2*30  L=300   gnabar_dc=.07 gkbar_dc=.0175 gl_dc=.167e-3 }
is		{ diam=2*5   L=100   gnabar_dc=.6  gkbar_dc=.1    gl_dc=1e-3    }
forsec "myelin" { diam=2*8   L=400   gnabar_dc=0   gkbar_dc=0     gl_dc=.05e-3  }
forsec "node"   { diam=2*10  L=75    gnabar_dc=.6  gkbar_dc=.1    gl_dc=3e-3    }
extra		{ diam=2*5   L=500   gnabar_dc=.07 gkbar_dc=.0175 gl_dc=.167e-3 }

proc init() {
	finitialize(v_init)
	fcurrent()
}

// use following for exact resting potential of 0
/*
proc init() {
	finitialize(v_init)
	fcurrent()
	forall {
		el_dc = (ina + ik)/gl_dc + v
	}
}
*/

Loading data, please wait...