Irregular spiking in NMDA-driven prefrontal cortex neurons (Durstewitz and Gabriel 2006)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:82784
Slow N-Methyl-D-aspartic acid (NMDA) synaptic currents are assumed to strongly contribute to the persistently elevated firing rates observed in prefrontal cortex (PFC) during working memory. During persistent activity, spiking of many neurons is highly irregular. ... The highest interspike-interval (ISI) variability occurred in a transition regime where the subthreshold membrane potential distribution shifts from mono- to bimodality, ... Predictability within irregular ISI series was significantly higher than expected from a noise-driven linear process, indicating that it might best be described through complex (potentially chaotic) nonlinear deterministic processes. Accordingly, the phenomena observed in vitro could be reproduced in purely deterministic biophysical model neurons. High spiking irregularity in these models emerged within a chaotic, close-to-bifurcation regime characterized by a shift of the membrane potential distribution from mono- to bimodality and by similar ISI return maps as observed in vitro. ... NMDA-induced irregular dynamics may have important implications for computational processes during working memory and neural coding.
Reference:
1 . Durstewitz D, Gabriel T (2007) Dynamical basis of irregular spiking in NMDA-driven prefrontal cortex neurons. Cereb Cortex 17:894-908 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism: Neocortex; Prefrontal cortex (PFC);
Cell Type(s): Neocortex V1 L6 pyramidal corticothalamic cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I K; I Potassium;
Gap Junctions:
Receptor(s): GabaA; AMPA; NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; MATLAB;
Model Concept(s): Activity Patterns; Working memory; Calcium dynamics; Bifurcation;
Implementer(s): Durstewitz, Daniel [daniel.durstewitz at plymouth.ac.uk];
Search NeuronDB for information about:  Neocortex V1 L6 pyramidal corticothalamic cell; GabaA; AMPA; NMDA; I Na,p; I Na,t; I L high threshold; I K; I Potassium;
: Persistent Na+ channel under D1
: from Durstewitz & Gabriel (2006), Cerebral Cortex

NEURON {
	SUFFIX NapDA
	USEION na WRITE ina
	RANGE gNapbar, gna, ena
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
}

PARAMETER {
	gNapbar= 0.0022 (mho/cm2) <0,1e9>
	ena = 55 (mV)
}

ASSIGNED {
        v (mV)
	ina (mA/cm2)
	gna (mho/cm2)
}

STATE {
	m 
        h 
}

INITIAL {
	m = malf(v)/(malf(v)+mbet(v))
	h = half(v)/(half(v)+hbet(v))
}

BREAKPOINT {
	SOLVE states METHOD derivimplicit
	gna = gNapbar*m*h
	ina = gna*(v-ena)
}

DERIVATIVE states {
	m' = (1-m)*malf(v)-m*mbet(v)
	h' = ((1-h)*half(v)-h*hbet(v))/2.0
}

UNITSOFF

FUNCTION malf(v(mV)) (/ms) { 
	LOCAL va 
	va=v+12
	if (fabs(va)<1e-04) {
	   malf= -0.2816*(-9.3 - va*0.5)
	} 
	else {
	   malf = -0.2816*va/(-1+exp(-va/9.3))
	}
}

FUNCTION mbet(v(mV)) (/ms) { 
	LOCAL vb 
	vb=v-15
	if (fabs(vb)<1e-04) {
	   mbet = 0.2464*(6 - vb*0.5)
	}
	else {
	   mbet = 0.2464*vb/(-1+exp(vb/6))
	}
}	

FUNCTION half(v(mV)) (/ms) { 
        half= 2.8e-5*(exp(-(v+42.8477)/4.0248))
}

FUNCTION hbet(v(mV)) (/ms) { 
        hbet= 0.02/(1+exp(-(v-413.9284)/148.2589))
}
	
UNITSON

Loading data, please wait...