LGMD impedance (Dewell & Gabbiani 2019)

 Download zip file 
Help downloading and running models
Accession:256024
"How neurons filter and integrate their complex patterns of synaptic inputs is central to their role in neural information processing . Synaptic filtering and integration are shaped by the frequency-dependent neuronal membrane impedance. Using single and dual dendritic recordings in vivo, pharmacology, and computational modeling, we characterized the membrane impedance of a collision detection neuron in the grasshopper, Schistocerca americana. This neuron, the lobula giant movement detector (LGMD), exhibits consistent impedance properties across frequencies and membrane potentials. Two common active conductances gH and gM, mediated respectively by hyperpolarization-activated cyclic nucleotide gated (HCN) channels and by muscarine sensitive M-type K+ channels, promote broadband integration with high temporal precision over the LGMD's natural range of membrane potentials and synaptic input frequencies. Additionally, we found that a model based on the LGMD's branching morphology increased the gain and decreased the delay associated with the mapping of synaptic input currents to membrane potential. More generally, this was true for a wide range of model neuron morphologies, including those of neocortical pyramidal neurons and cerebellar Purkinje cells. These findings show the unexpected role played by two widespread active conductances and by dendritic morphology in shaping synaptic integration."
Reference:
1 . Dewell RB, Gabbiani F (2019) Active membrane conductances and morphology of a collision detection neuron broaden its impedance profile and improve discrimination of input synchrony. J Neurophysiol [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Dendrite;
Brain Region(s)/Organism:
Cell Type(s): Locust Lobula Giant Movement Detector (LGMD) neuron;
Channel(s): I h; I M;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Detailed Neuronal Models; Synaptic Integration; Membrane Properties;
Implementer(s): Dewell, Richard Burkett [dewell at bcm.edu];
Search NeuronDB for information about:  I M; I h; 
TITLE chirp current

COMMENT
-----------------------------------------------------------------------------

    chirp current injection
    ==================================================

 IMPLEMENTATION

  This mechanism is implemented as a nonspecific current defined as a
  point process, mimicking a current-clamp stimulation protocol, injecting
  a chirp waveform with a constant frequency or linearly or exponentially changing frequencies.
  
	f = t-t1	: time relative to start of chirp

	'exponential'
	chirp = amp*sin(f*exp(f*beta)*Finit*pi)
	'linear'
	chirp = amp*sin(pi*beta*f^2)
	'constant'
	chirp = amp*sin(2*pi*Finit*f)

	amp, beta, linear, Finit, t1, dur

 PARAMETERS

  This mechanism takes the following parameters:

	amp	=	0.0 (nA)	: amplitude of injected current. positive values of i depolarize the cell
	t1 = 	0.0 (ms)	: starting time of the stimulation.
	dur =	0.0 (ms)	: duration of chirp current
	Finit =	0.0 (Hz)	: initial frequency of the chirp current.
	beta =	0.0 (Hz/s)	: rate of change of chirp frequency
	ctype =	1 (1)		: chirp type. 0 = constant, 1 = linear (default), 2 = exponential
	
-----------------------------------------------------------------------------
ENDCOMMENT


:INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
    POINT_PROCESS chirp
    RANGE amp, t1, dur, Finit, beta, ctype
    NONSPECIFIC_CURRENT i
}

UNITS {
    (nA) = (nanoamp) 
    (mV) = (millivolt)
}

PARAMETER {
	amp	=	1.0	(nA)	: amplitude of injected current
	t1 = 	1000 (ms)	: starting time of the stimulation.
	dur =	20000 (ms)	: duration of chirp current
	Finit =	0.05 (Hz)	: initial frequency of the chirp current.
	beta =	0.24 (Hz/s)	: rate of change of chirp frequency
	ctype =	2	(1)		: chirp type. 0 = constant, 1 = linear, 2 = exponential
}

ASSIGNED {
	i	(nA)			: fluctuating current
}


BREAKPOINT {
	LOCAL tc,  pi, uf, mstos
	:tc is time from start of chirp (s)

	mstos = 1000 (ms/s)	: conversion of ms to s
	uf = 1 (s)			: unit conversion for exponential chirp. beta is in Hz for exponential chirp

	pi=3.14159265358979323846
	:pi=PI
	
    if ((t < t1) || (t > t1+dur)) {  
    	i = 0
    } else {
    	tc=(t-t1)/mstos
    	if (ctype == 0) {
    		i = -amp*sin(2*pi*Finit*tc)
    	} else if (ctype == 1) {
    		i = -amp*sin(pi*beta*(tc+Finit/beta)^2)
    	} else if (ctype == 2) {
    		i = -amp*sin(2*pi*Finit*tc*exp(tc*beta*uf))
    	}
    }
}

Loading data, please wait...