COMMENT
Two state kinetic scheme synapse described by rise time tau1,
and decay time constant tau2. The normalized peak condunductance is 1.
Decay time MUST be greater than rise time.
The solution of A->G->bath with rate constants 1/tau1 and 1/tau2 is
A = a*exp(-t/tau1) and
G = a*tau2/(tau2-tau1)*(-exp(-t/tau1) + exp(-t/tau2))
where tau1 < tau2
If tau2-tau1 -> 0 then we have a alphasynapse.
and if tau1 -> 0 then we have just single exponential decay.
The factor is evaluated in the
initial block such that an event of weight 1 generates a
peak conductance of 1.
Because the solution is a sum of exponentials, the
coupled equations can be solved as a pair of independent equations
by the more efficient cnexp method.
20121120 TMM & MJH modified to be current based synapse
20120413 TMM modified to include conductance saturation: the
conductance, g, will not exceed "saturation"; however when simulated
past saturation, g will take longer to drop back below saturation
(the A, B parameters climb arbitrarily high).
ENDCOMMENT
NEURON {
POINT_PROCESS Exp2SynCur
RANGE tau1, tau2, e, i, saturation, Vrest
: Vrest will replace v (Vm) to make this a current based rather than
: conductance based synapse
NONSPECIFIC_CURRENT i
RANGE g
}
UNITS {
(nA) = (nanoamp)
(mV) = (millivolt)
(uS) = (microsiemens)
}
PARAMETER {
tau1=.1 (ms) <1e-9,1e9>
tau2 = 10 (ms) <1e-9,1e9>
e=-70 (mV) : default originally used to be 0 (mV)
saturation = 1e9 (uS) : assign in hoc (typical real synapse
: value 0.0004 = 0.4 nS) A large value disables the limiting effect.
Vrest = -62.5 (mV) : could be any number as ends up being
: a multiplicative factor of the conductance
}
ASSIGNED {
v (mV)
i (nA)
g (uS)
factor
}
STATE {
A (uS)
B (uS)
}
INITIAL {
LOCAL tp
if (tau1/tau2 > .9999) {
tau1 = .9999*tau2
}
A = 0
B = 0
tp = (tau1*tau2)/(tau2 - tau1) * log(tau2/tau1)
factor = -exp(-tp/tau1) + exp(-tp/tau2)
factor = 1/factor
}
BREAKPOINT {
SOLVE state METHOD cnexp
g = B - A
if (g>saturation) {
g = saturation
}
: i = g*(v - e)
i = g*(Vrest - e) : current version of above : driving force is const.
}
DERIVATIVE state {
A' = -A/tau1
B' = -B/tau2
}
NET_RECEIVE(weight (uS)) {
A = A + weight*factor
B = B + weight*factor
}